An even number of (at least 8) regular tetrahedra can be connected along their edges to form a ring in a way that allows them to be continuously rotated “inside-out” without disconnecting. Such configurations are commonly referred to as kaleidocycles. Shown above are kaleidocycles with 8, 10, and 12 tetrahedra exhibiting 4, 5, and 6-fold rotational symmetry, respectively. There has to be at least 8 regular tetrahedra, because any less would result in the tetrahedra colliding into each other at certain instances of the rotation. You can even make your own paper model using this guide.

Mathematica code:

v1[t_] := 
{Cos[t], 0, Sin[t]}

v2[t_, a_] := 
 1/Sqrt[1 + Sin[t]^2 Tan[a]^2] {-Sin[t], -Sin[t] Tan[a], Cos[t]}

v3[t_, a_] := 
 1/Sqrt[1 + Sin[t]^2 Tan[a]^2] {-Sin[t]^2 Tan[a], 1, Cos[t] Sin[t] Tan[a]}

P[t_, a_] := 
{v3[t, a][[2]]/Tan[a] - v3[t, a][[1]], 0, -v3[t, a][[3]]/2}

Q[t_, a_] := 
{v3[t, a][[2]]/Tan[a], v3[t, a][[2]], v3[t, a][[3]]/2}

vertices[t_, a_] := 
{P[t, a] - Sqrt[2]/2 v1[t], P[t, a] + Sqrt[2]/2 v1[t],
 Q[t, a] - Sqrt[2]/2 v2[t, a], Q[t, a] + Sqrt[2]/2 v2[t, a]}

Tetrahedron[T_, t_, a_, o_] :=
 Table[
  {FaceForm[White], Opacity[o], EdgeForm[Thick],
   Polygon[
    Table[
     T[vertices[t, a][[1 + Mod[i + j, 4]]]], {i, 1, 3, 1}]]},
  {j, 0, 3, 1}]

Kaleidocycle[pr_, t_, n_, o_, A_] := Graphics3D[
  Rotate[
   Table[
    Rotate[
     Table[
      Tetrahedron[T, t, 2 Pi/n, o],
      {T, {TransformationFunction[IdentityMatrix[4]], 
        ReflectionTransform[{-Sin[2 Pi/n], Cos[2 Pi/n], 0}]}}],
     r*4 Pi/n, {0, 0, 1}],
    {r, 0, n - 1, 1}],
   A*Sin[t], {0, 1, 0}],
  PlotRange -> pr, ImageSize -> 500, Axes -> False, Boxed -> False, 
  Lighting -> "Neutral", ViewPoint -> {0, 0, 2}, Background -> White ]

Manipulate[
Kaleidocycle[pr, t, n, o, A],
 {pr, 1.5, 50}, {t, 0, 2 Pi}, {n, 8, 16, 1},{o, 1, 0}, {{A, 0}, 0, 2 Pi}]